This is xnu-11215.1.10. See this file in: xnu-8792.81.2 (MacOS 18, Darwin 22) xnu-8019 (MacOS 17.0, Darwin 21) xnu-6153.11.26 (MacOS 15.0, Darwin 19) xnu-4903.221.2 (MacOS 14.0, Darwin 18) xnu-4570.41.2 (MacOS 13.3, Darwin 17) xnu-3789.70.16 (MacOS 12.6, Darwin 16) xnu-3248.20.55 (MacOS 11.2, Darwin 15) xnu-2782.40.9 (MacOS 10.10.5, Darwin 14) xnu-2422.115.4 (MacOS 10.9.5, Darwin 13) xnu-2050.24.15 (MacOS 10.8.4, Darwin 12) xnu-1699.32.7 (MacOS 10.7.5, Darwin 11) xnu-1504.15.3 (MacOS 10.6.8, Darwin 10) xnu-1228.15.4 (MacOS 10.5.8, Darwin 9)

// To apply, at the top of xnu.git:
// $ spatch --max-width=80 --use-gitgrep --in-place --include-headers --sp-file tools/cocci/zalloc.cocci -dir .
//
// This might need to be run several times

@ using "zalloc.iso" @
expression E, F;
type T;
identifier V;
identifier NI =~ "_NULL$";
@@
(

(
  E = zalloc_flags(F, \(Z_NOFAIL\|Z_NOFAIL | ...\));
|
  E = kalloc_type(F, \(Z_NOFAIL\|Z_NOFAIL | ...\));
|
  E = \(kalloc_data\|kalloc_flags\)(F, \(Z_NOFAIL\|Z_NOFAIL | ...\));
|
- E = zalloc(F);
+ E = zalloc_flags(F, Z_WAITOK | Z_NOFAIL);
|
  E = zalloc_flags(F, \(Z_WAITOK\| Z_WAITOK | ...\)
+ | Z_NOFAIL
  );
|
  E = kalloc_type(T, \(Z_WAITOK\| Z_WAITOK | ...\)
+ | Z_NOFAIL
  );
|
  E = \(kalloc_data\|kalloc_flags\)(sizeof(F), \(Z_WAITOK\| Z_WAITOK | ...\)
+ | Z_NOFAIL
  );
|
- E = kalloc(sizeof(F));
+ E = kalloc_flags(sizeof(F), Z_WAITOK | Z_NOFAIL);
)
  ...
(
- if (\(E\|E != 0\|E != NULL\|E != NI\)) {
  ...
- }
|
- if (\(!E\|E == 0\|E == NULL\|E == NI\)) {
- ...
- }
|
- assert(\(E\|E != 0\|E != NULL\|E != NI\));
)

|

(
  T V = zalloc_flags(F, \(Z_NOFAIL\|Z_NOFAIL | ...\));
|
  T V = kalloc_type(T, \(Z_NOFAIL\|Z_NOFAIL | ...\));
|
  T V = \(kalloc_data\|kalloc_flags\)(F, \(Z_NOFAIL\|Z_NOFAIL | ...\));
|
- T V = kalloc(sizeof(F));
+ T V = kalloc_flags(sizeof(F), Z_WAITOK | Z_NOFAIL);
|
  T V = kalloc_type(T, \(Z_WAITOK\| Z_WAITOK | ...\)
+ | Z_NOFAIL
  );
|
  T V = \(kalloc_data\|kalloc_flags\)(sizeof(F), \(Z_WAITOK\| Z_WAITOK | ...\)
+ | Z_NOFAIL
  );
)
  ...
(
- if (\(V\|V != 0\|V != NULL\|V != NI\)) {
  ...
- }
|
- if (\(!V\|V == 0\|V == NULL\|V == NI\)) {
- ...
- }
|
- assert(\(V\|V != 0\|V != NULL\|V != NI\));
)

)

// vim:ft=diff: